1 files changed, 75 insertions, 0 deletions
diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..2d945d6
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,75 @@
+# Process this file with autoconf to produce a configure script.
+#
+# Copyright (C) 2013, 2014  Patrick "P. J." McDermott
+#
+# This program is free software: you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation, either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+AC_INIT([OPK Build Helper Tools], [3.0.0-beta4],
+	[mailto:proteanos-dev@lists.proteanos.com], [opkhelper],
+	[http://www.proteanos.com/dev/opkhelper/])
+AC_CONFIG_AUX_DIR([build-aux])
+AC_CONFIG_SRCDIR([src/oh-installfiles.sh])
+
+AM_INIT_AUTOMAKE([gnu dist-bzip2 dist-xz subdir-objects])
+
+AC_ARG_WITH(
+	[sh],
+	[AS_HELP_STRING([--with-sh], [POSIX-conformant shell with `local'])],
+	dnl This `dnl' is needed to workaround Vim syntax highlighting.
+	[
+		case "${withval}" in
+			'yes'|'')
+				AC_MSG_ERROR([--with-sh requires an argument])
+				;;
+			'no')
+				AC_MSG_ERROR([sh is required])
+				;;
+			*)
+				SH="${withval}"
+				;;
+		esac
+	],
+	[
+		AC_PATH_PROG([SH], [sh])
+		if test -z "${SH}"; then
+			AC_MSG_ERROR([sh not found])
+		fi
+	]
+)
+
+AC_ARG_ENABLE(
+	[multiarch-libdir],
+	[AS_HELP_STRING(
+		[--disable-multiarch-libdir],
+		[do not use multiarch library paths in packages]
+	)],
+	[
+		opt='multiarch-libdir'
+		case "${enableval}" in
+			'yes'|'no') ;;
+			*) AC_MSG_ERROR(
+				[bad value `${enableval}' for ${opt} option]) ;;
+		esac
+		dnl This `dnl' is needed to workaround Vim syntax highlighting.
+		multiarch_libdir="${enableval}"
+	],
+	[
+		multiarch_libdir='yes'
+	]
+)
+
+AC_SUBST([SH])
+AC_SUBST([multiarch_libdir])
+AC_CONFIG_FILES([Makefile])
+AC_OUTPUT()