# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2013, 2014  Patrick "P. J." McDermott
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

AC_INIT([opkhelper], [3.1.4+dev],
	[mailto:proteanos-dev@lists.proteanos.com], [opkhelper],
	[http://www.proteanos.com/dev/opkhelper/])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_SRCDIR([src/oh-installfiles.sh])

AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])

AC_ARG_WITH(
	[sh],
	[AS_HELP_STRING([--with-sh=PATH],
		[POSIX-conformant shell with `local'])],
	dnl This `dnl' is needed to workaround Vim syntax highlighting.
	[
		case "${withval}" in
			'yes'|'')
				AC_MSG_ERROR([--with-sh requires an argument])
				;;
			'no')
				AC_MSG_ERROR([sh is required])
				;;
			*)
				SH="${withval}"
				;;
		esac
	],
	[
		AC_PATH_PROG([SH], [sh])
		if test -z "${SH}"; then
			AC_MSG_ERROR([sh not found])
		fi
	]
)

AC_ARG_WITH(
	[libopkbuild],
	[AS_HELP_STRING([--with-libopkbuild=PATH],
		[path to libopkbuild.shso.2])],
	[
		opt='libopkbuild'
		case "${withval}" in
			'yes'|'')
				AC_MSG_ERROR(
					[--with-${opt} requires an argument])
				;;
			'no')
				AC_MSG_ERROR([${opt} is required])
				;;
			*)
				LIBOPKBUILD="${withval}"
				;;
		esac
	],
	[
		AC_MSG_CHECKING([for libopkbuild])
		for f in /usr/share/sh/libopkbuild.shso.2 \
				/usr/local/share/sh/libopkbuild.shso.2; do
			if test -r "${f}"; then
				LIBOPKBUILD="${f}"
				AC_MSG_RESULT([${f}])
				break
			fi
		done
		if test -z "${LIBOPKBUILD}"; then
			AC_MSG_ERROR([libopkbuild not found])
		fi
	]
)

AC_ARG_WITH(
	[readelf],
	[AS_HELP_STRING([--with-readelf=PATH], [path to readelf])],
	[
		case "${withval}" in
			'yes'|'')
				AC_MSG_ERROR(
					[--with-readelf requires an argument])
				;;
			'no')
				AC_MSG_ERROR([readelf is required])
				;;
			*)
				READELF="${withval}"
				;;
		esac
	],
	[
		AC_PATH_PROG([READELF], [readelf])
		if test -z "${READELF}"; then
			AC_MSG_ERROR([readelf not found])
		fi
	]
)

AC_ARG_WITH(
	[opkg],
	[AS_HELP_STRING([--with-opkg=PATH], [path to opkg])],
	[
		case "${withval}" in
			'yes'|'')
				AC_MSG_ERROR([--with-opkg requires an argument])
				;;
			'no')
				AC_MSG_ERROR([opkg is required])
				;;
			*)
				OPKG="${withval}"
				;;
		esac
	],
	[
		AC_PATH_PROG([OPKG], [opkg])
		if test -z "${OPKG}"; then
			AC_MSG_ERROR([opkg not found])
		fi
	]
)

AC_ARG_ENABLE(
	[multiarch-libdir],
	[AS_HELP_STRING(
		[--disable-multiarch-libdir],
		[do not use multiarch library paths in packages]
	)],
	[
		opt='multiarch-libdir'
		case "${enableval}" in
			'yes'|'no') ;;
			*) AC_MSG_ERROR(
				[bad value `${enableval}' for ${opt} option]) ;;
		esac
		dnl This `dnl' is needed to workaround Vim syntax highlighting.
		multiarch_libdir="${enableval}"
	],
	[
		multiarch_libdir='yes'
	]
)

AC_ARG_WITH(
	[opkbuild-helpers],
	[AS_HELP_STRING([--with-opkbuild-helpers=PATH],
		[specify directory to install opkbuild helper script])],
	[
		opt='opkbuild-helpers'
		case "${withval}" in
			'yes'|'')
				AC_MSG_ERROR(
					[--with-${opt} requires an argument])
				;;
			'no')
				AC_MSG_ERROR([${opt} is required])
				;;
			*)
				helperdir="${withval}"
				;;
		esac
	],
	[
		helperdir='$(datadir)/opkbuild/helpers'
	]
)

AC_SUBST([SH])
AC_SUBST([LIBOPKBUILD])
AC_SUBST([READELF])
AC_SUBST([OPKG])
AC_SUBST([multiarch_libdir])
AC_SUBST([helperdir])
AC_CONFIG_FILES([Makefile])
AC_OUTPUT()