# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2013  Patrick "P. J." McDermott
#
# This file is part of the ProteanOS Archive Manager.
#
# The ProteanOS Archive Manager is free software: you can redistribute
# it and/or modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation, either version 3 of the
# License, or (at your option) any later version.
#
# The ProteanOS Archive Manager is distributed in the hope that it
# will be useful, but WITHOUT ANY WARRANTY; without even the implied
# warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
# See the GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with the ProteanOS Archive Manager.  If not, see
# <http://www.gnu.org/licenses/>.

AC_INIT([ProteanOS Archive Manager], [2.0.0],
	[mailto:proteanos-dev@lists.proteanos.com], [pro-archman],
	[http://www.proteanos.com/dev/pro-archman/])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_SRCDIR([src/main.sh])

AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])
AM_SILENT_RULES([yes])

AM_CONDITIONAL([IN_GIT],
	[test -d "${srcdir}/.git" && command -v git >/dev/null 2>&1])

AC_ARG_WITH(
	[sh],
	[AS_HELP_STRING([--with-sh=PATH],
		[POSIX-conformant shell with `local'])],
	dnl This `dnl' is needed to workaround Vim syntax highlighting.
	[
		case "${withval}" in
			'yes'|'')
				AC_MSG_ERROR([--with-sh requires an argument])
				;;
			'no')
				AC_MSG_ERROR([sh is required])
				;;
			*)
				SH="${withval}"
				;;
		esac
	],
	[
		AC_PATH_PROG([SH], [sh])
		if test -z "${SH}"; then
			AC_MSG_ERROR([sh not found])
		fi
	]
)

AC_SUBST([SH])
AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([config.sh])
AC_OUTPUT()