# Copyright (C) 2012 Patrick "P. J." McDermott
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

use strict;
use warnings;

use MarkdownBook::Document;
use MarkdownBook::Section::HTML;
use HTML::Template;

package MarkdownBook::Document::HTML;

our @ISA = qw(MarkdownBook::Document);

sub parse
{
	my ($self) = @_;
	my $file = $self->{'book'}->dir() . '/' . $self->{'file'} . '.html.in';
	my @headers;
	my $header;
	my @secnums = (0, 0);
	my $curlev = -1;
	my $newlev;
	my $secstr;

	$self->{'tree'} = HTML::TreeBuilder->new();
	$self->{'tree'}->parse_file($file);

	@{$self->{'tree_body'}} = MarkdownBook::HTMLTree::find_elements_by_tag_names(
		$self->{'tree'}, ('body'));

	if ($self->{'type'} eq 'index') {
		return;
	}
	
	@headers = MarkdownBook::HTMLTree::find_elements_by_tag_names(
		@{$self->{'tree_body'}}[0], ('h1', 'h2'));

	foreach $header (@headers) {

		# Calculate section number.
		$newlev = $header->tag();
		$newlev =~ s/^h(\d)$/$1/;
		if ($newlev != $curlev) {
			foreach (@secnums[$newlev .. $#secnums]) {
				$_ = 0;
			}
		}
		$curlev = $newlev;
		++$secnums[$newlev - 1];
		$secstr = join('.', @secnums);
		$secstr = $self->{'id'} . '.' . $secstr;
		$secstr =~ s/(\.0)*$//;

		push(@{$self->{'sections'}},
			MarkdownBook::Section::HTML->new($self, $secstr, $header));
	}
}

sub output
{
	my ($self) = @_;

	my $doc_tmpl;
	my %opt_end_tags;
	my $elem;
	my $body;
	my $doc_fh;

	$doc_tmpl = HTML::Template->new(filename => 'include/document.tmpl');

	# Don't omit any end tags.
	%opt_end_tags = map([$_ => 0], %HTML::Element::optionalEndTag);

	foreach $elem (@{$self->{'tree_body'}}[0]->content_list()) {
		# It's safe to assume (ref($elem) eq 'HTML::Element').
		$body .= $elem->as_HTML('<>&', '', \%opt_end_tags) . "\n";
	}

	$doc_tmpl->param(IS_INDEX => ($self->{'type'} eq 'index'));

	$doc_tmpl->param(BOOK_TITLE => $self->{'book'}->title());
	$doc_tmpl->param(TITLE => $self->{'title'});
	$doc_tmpl->param(CHAPT_TITLE => $self->full_title());

	if (defined($self->{'prev'})) {
		$doc_tmpl->param(PREV_LINK => $self->{'prev'}->file() . '.html');
		$doc_tmpl->param(PREV_TITLE => $self->{'prev'}->title());
	} else {
		$doc_tmpl->param(PREV_LINK => undef);
		$doc_tmpl->param(PREV_TITLE => undef);
	}
	if (defined($self->{'next'})) {
		$doc_tmpl->param(NEXT_LINK => $self->{'next'}->file() . '.html');
		$doc_tmpl->param(NEXT_TITLE => $self->{'next'}->title());
	} else {
		$doc_tmpl->param(NEXT_LINK => undef);
		$doc_tmpl->param(NEXT_TITLE => undef);
	}

	$doc_tmpl->param(BODY => $body);

	open($doc_fh, '>', $self->file_path() . '.html');
	$doc_tmpl->output(print_to => $doc_fh);
	close($doc_fh);
}

1;