1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2017 Patrick McDermott
#
# This file is part of fbcon2png.
#
# fbcon2png is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 2 of the License, or
# (at your option) any later version.
#
# fbcon2png is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with fbcon2png. If not, see <http://www.gnu.org/licenses/>.
AC_INIT([fbcon2png], [0.1.0], [mailto:pj@pehjota.net], [fbcon2png])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([src/main.c])
AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])
AM_SILENT_RULES([yes])
AM_CONDITIONAL([IN_GIT],
[test -d "${srcdir}/.git" && command -v git >/dev/null 2>&1])
GETTEXT_PACKAGE="${PACKAGE}"
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["${GETTEXT_PACKAGE}"],
[Define the gettext package to be used.])
AM_GNU_GETTEXT([external])
AC_PROG_CC()
AM_PROG_CC_C_O()
AX_CFLAGS_WARN_ALL() dnl Adds -Wall or equivalent
AX_CHECK_COMPILE_FLAG([-Wpedantic], [AX_APPEND_FLAG([-Wpedantic])])
AX_CHECK_COMPILE_FLAG([-Wextra], [AX_APPEND_FLAG([-Wextra])])
AC_ARG_ENABLE([gcc-warnings],
[AS_HELP_STRING([--enable-gcc-warnings], [turn on many GCC warnings])],
[case "${enableval}" in yes|no) gcc_warnings=${enableval};;
*) AC_MSG_ERROR(
[bad value ${enableval} for gcc-warnings option]);;
esac],
[
gcc_warnings=no
gl_GCC_VERSION_IFELSE([4], [6],
[test -d "${srcdir}/.git" && gcc_warnings=yes])
]
)
if test "x${gcc_warnings}" = 'xyes'; then
nowarns=''
nowarns="${nowarns} -Wsystem-headers"
gl_MANYWARN_ALL_GCC([warns])
gl_MANYWARN_COMPLEMENT([warns], [${warns}], [${nowarns}])
for warn in ${warns}; do
gl_WARN_ADD([${warn}])
done
AC_SUBST([WARN_CFLAGS])
fi
AX_CHECK_COMPILE_FLAG([-fdiagnostics-color=auto],
[AX_APPEND_FLAG([-fdiagnostics-color=auto])])
AC_ARG_ENABLE([address-sanitization],
[AS_HELP_STRING([--enable-address-sanitization],
[turn on AddressSanitizer (if available)])],
[case "${enableval}" in yes|no) address_sanitization=${enableval};;
*) AC_MSG_ERROR(
[bad value ${enableval} for address-sanitization option]
);;
esac],
[
address_sanitization=no
gl_GCC_VERSION_IFELSE([4], [8],
[test -d "${srcdir}/.git" && address_sanitization=yes])
]
)
if test "x${address_sanitization}" = 'xyes'; then
AX_CHECK_COMPILE_FLAG([-fsanitize=address],
[AX_APPEND_FLAG([-fsanitize=address], [ASAN_CFLAGS])])
AX_CHECK_COMPILE_FLAG([-fno-omit-frame-pointer],
[AX_APPEND_FLAG([-fno-omit-frame-pointer], [ASAN_CFLAGS])])
AC_SUBST([ASAN_CFLAGS])
fi
PKG_PROG_PKG_CONFIG()
PKG_CHECK_MODULES([LIBPNG], [libpng])
LIBPNG_CFLAGS="$(printf ' %s' "${LIBPNG_CFLAGS}" | \
sed 's/ -I/ -isystem/g;')"
AC_CONFIG_FILES([Makefile po/Makefile.in])
AC_CONFIG_HEADERS([config.h])
AC_OUTPUT()
|
