1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Process this file with autoconf to produce a configure script.
#
# Copyright (C) 2017 Patrick McDermott
#
# This file is part of wolfssl-util.
#
# wolfssl-util is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 2 of the License, or
# (at your option) any later version.
#
# wolfssl-util is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with wolfssl-util. If not, see <http://www.gnu.org/licenses/>.
AC_INIT([Unofficial wolfSSL Utility], [0.1.0],
[mailto:patrick.mcdermott@libiquity.com], [wolfssl-util])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([src/main.c])
AM_INIT_AUTOMAKE([gnu check-news dist-bzip2 dist-xz subdir-objects])
AM_SILENT_RULES([yes])
AM_CONDITIONAL([IN_GIT],
[test -d "${srcdir}/.git" && command -v git >/dev/null 2>&1])
AC_PROG_CC()
AM_PROG_CC_C_O()
CFLAGS=''
AX_CFLAGS_WARN_ALL() dnl Adds -Wall or equivalent
AX_CHECK_COMPILE_FLAG([-Wpedantic], [AX_APPEND_FLAG([-Wpedantic])])
AX_CHECK_COMPILE_FLAG([-Wextra], [AX_APPEND_FLAG([-Wextra])])
AC_ARG_ENABLE([gcc-warnings],
[AS_HELP_STRING([--enable-gcc-warnings], [turn on many GCC warnings])],
[case "${enableval}" in yes|no) gcc_warnings=${enableval};;
*) AC_MSG_ERROR(
[bad value ${enableval} for gcc-warnings option]);;
esac],
[
gcc_warnings=no
test -d "${srcdir}/.git" && gcc_warnings=yes
]
)
if test "x${gcc_warnings}" = 'xyes'; then
nowarns=''
nowarns="${nowarns} -Wsystem-headers"
gl_MANYWARN_ALL_GCC([warns])
gl_MANYWARN_COMPLEMENT([warns], [${warns}], [${nowarns}])
for warn in ${warns}; do
gl_WARN_ADD([${warn}])
done
AC_SUBST([WARN_CFLAGS])
fi
AX_CHECK_COMPILE_FLAG([-fdiagnostics-color=auto],
[AX_APPEND_FLAG([-fdiagnostics-color=auto])])
AC_ARG_ENABLE([address-sanitization],
[AS_HELP_STRING([--enable-address-sanitization],
[turn on AddressSanitizer (if available)])],
[case "${enableval}" in yes|no) address_sanitization=${enableval};;
*) AC_MSG_ERROR(
[bad value ${enableval} for address-sanitization option]
);;
esac],
[address_sanitization=no]
)
if test "x${address_sanitization}" = 'xyes'; then
AX_CHECK_COMPILE_FLAG([-fsanitize=address],
[AX_APPEND_FLAG([-fsanitize=address], [ASAN_CFLAGS])])
AX_CHECK_COMPILE_FLAG([-fno-omit-frame-pointer],
[AX_APPEND_FLAG([-fno-omit-frame-pointer], [ASAN_CFLAGS])])
AC_SUBST([ASAN_CFLAGS])
fi
AX_APPEND_FLAG([-DTFM_TIMING_RESISTANT])
AX_APPEND_FLAG([-DECC_TIMING_RESISTANT])
for flag in -Os -s -fno-unwind-tables -fno-asynchronous-unwind-tables \
-ffunction-sections -fdata-sections -Wl,--gc-sections \
-fstack-protector-strong -flto \
-Wl,-z,now -Wl,--hash-style=sysv -Wl,--build-id=none; do
AX_CHECK_COMPILE_FLAG([${flag}], [AX_APPEND_FLAG([${flag}])])
done
CA_CERTS='/etc/ssl/certs'
AC_ARG_WITH([ca-certificates],
[AS_HELP_STRING([--with-ca-certificates=PATH],
[path to CA root certificates])],
[
case "${withval}" in
'yes'|'')
HAVE_CA_CERTS=1
;;
'no')
HAVE_CA_CERTS=0
;;
*)
HAVE_CA_CERTS=1
CA_CERTS="${withval}"
;;
esac
],
[
AC_MSG_CHECKING([for CA root certificates])
if test -d "${CA_CERTS}"; then
AC_MSG_RESULT([${CA_CERTS}])
HAVE_CA_CERTS=1
else
AC_MSG_RESULT([no])
HAVE_CA_CERTS=0
fi
]
)
AC_DEFINE_UNQUOTED([HAVE_CA_CERTS], [${HAVE_CA_CERTS}],
[Define to 1 to verify certificates against installed CA root
certificates.])
AC_DEFINE_UNQUOTED([CA_CERTS], ["${CA_CERTS}"],
[Define to the path to CA root certificates.])
PKG_PROG_PKG_CONFIG()
PKG_CHECK_MODULES([WOLFSSL], [wolfssl])
WOLFSSL_CFLAGS="$(printf ' %s' "${WOLFSSL_CFLAGS}" | \
sed 's/ -I/ -isystem/g;')"
AC_CONFIG_FILES([Makefile])
AC_CONFIG_HEADERS([config.h])
AC_OUTPUT()
|
